10 'Ref : Journal - INNOVATIVE ACR; July-Sep, 1997
20 'Submitted by Gaurav Saxena
30 'Date made : Nov 25, '97
40 'The program calculates results for GI ducts.
50 DIM O(20)
60 COLOR 15,1
70 CLS:PRINT :PRINT
80 PRINT "A I R    D U C T     S I Z I N G"
90 PRINT "This program calculates friction drop in AIR DUCTS and diameter"
100 PRINT "of round duct required to carry the desired air quantity at a "
110 PRINT "given velocity"
120 PRINT
130 PRINT "English Units"
140 COLOR 15,4
150 PRINT
160 INPUT "Air quantity (ft3/min) :";Q
170 PRINT "Choose basis : 1) Velocity"
180 PRINT "               2) Friction"
190 INPUT "Choice (1/2) :";CHOICE
200 IF CHOICE >2 OR CHOICE<1 THEN 190
210 ON CHOICE GOTO 220,660
220 INPUT "Given air velocity(ft/min) :";V
230 D=SQR(4/3.1417592#*Q/V)*12
240 F=2.7*D^(-1.22)*(V/1000)^1.82
250 COLOR 15,1
260 PRINT :PRINT "Diameter = ";D;"inches"
270 PRINT "Friction drop = ";F;"in. H2O/100ft"
280 PRINT
290 COLOR 15,4
300 INPUT "Want to convert to rectangular duct ?(y/n) :";X$
310 IF X$="y" OR X$="Y" THEN 370
320 IF X$="n" OR X$="N" THEN 340
330 GOTO 300
340 INPUT "Want to calculate round duct with new data :";D$
350 IF D$="n" OR D$="N" THEN END ELSE 160
360 PRINT
370 P$="Inches":DUMMY=D
380 PRINT "Input desired dimension of one side (inches)"
390 D=DUMMY
400 INPUT H
410 COLOR 15,1
420 IF H>300 OR H<1 THEN PRINT "Side must be between 1-300 inches":PRINT:GOTO 380
430 A=1:B=300:J=.01:N=0:I=1
440 IF ABS(B-A)>=J THEN 460
450 GOTO 500
460 C=(A+B)/2:GOSUB 610
470 IF M>=0 THEN 490
480 A=C:GOTO 440
490 B=C:GOTO 440
500 PRINT :PRINT "Round duct diameter :";D;P$
510 PRINT "Sides of equivalent rectangular duct :"
520 PRINT "Side A :";H;P$
530 PRINT "Side B :";C;P$
540 IF (H/C)>7 OR (C/H)>7 THEN PRINT "Aspect ratio>7 not recommended"
550 X$=""
560 COLOR 15,4
570 INPUT "Try another size (y/n) :";X$
580 IF X$="y" OR X$="Y" THEN 380
590 IF X$="n" OR X$="N" THEN 340
600 END
610 M=1.3^8*(D^(-8))*H^5*C^5-C^2-2*H*C-H^2
620 O(I)=M
630 IF O(I-1)<0 THEN N=N+1 ELSE N=0
640 I=I+1
650 RETURN
660 INPUT "Desired friction drop, (in.H2O/100ft) :";F
670 V=((F/2.7)*1000^1.82*12^1.22*(4*Q/3.1417592#)^61)^(1/2.43)
680 PRINT "Velocity = ";V;"fpm"
690 GOTO 230